;|

  LPTXT.LSP versione 1.0 [12.12.2004]
  Copyright (C) 2004 Claudio Piccini. All rights reserved
  www.cg-cad.com

  * Salva su file LINEE.TXT le coordinate x,y,z dei punti
    estremi delle linee presenti su un layer
  * Salva su file PUNTI.TXT le coordinate x,y,z dei punti
    presenti su un layer

|;

(defun myerror (s)                  
  (if (/= s "Function cancelled")
    (princ (strcat "\nError: " s))
  )
 (ripVar)
 (princ)
)

(defun salVar ()
 (setq orto (getvar "orthomode"))
 (setq snapp (getvar "osmode"))
 (setq snm (getvar "snapmode"))
 (setq piano (getvar "clayer"))  
 (setq nomeDir (getvar "dwgprefix"))
)

(defun ripVar ()
 (command "_redraw")
 (setvar "cmdecho" 1)
 (setvar "osmode" snapp)
 (setvar "snapmode" snm)
 (setvar "orthomode" orto)
 (setvar "clayer" piano)
 (setvar "cecolor" "BYLAYER")
 (setq *error* olderr)
 (princ)
)

(defun C:LPTXT (/ olderr s1 nEnt nomeLayer 
                  k ent str10 str11
                  snapp snm orto piano nomeDir 
                  nf1 nf2 f1 f2
 )
 (setq olderr *error* *error* myerror)
 (setvar "cmdecho" 0)
 (salVar)
 (setq nf1 (strcat nomeDir "linee.txt"))
 (setq nf2 (strcat nomeDir "punti.txt"))
 (command "osnap" "_nea")
 (setq s1 (entsel "\n Seleziona un'entita' di riferimento:"))
 (setq ent (entget (car s1)))
 (setq nomeLayer (cdr (assoc 8 ent))) ; legge il layer
 (setq s1 (ssget "X" (list (cons 8 nomeLayer))))
 (setq nEnt (sslength s1))
 (setq k 0)               ; contatore entita'
 (setq f1 (open nf1 "w")) ; apre il file LINEE.TXT
 (setq f2 (open nf2 "w")) ; apre il file PUNTI.TXT
 (repeat nEnt
  (setq ent (entget (ssname s1 k)))
  (if (= "LINE" (cdr (assoc 0 ent)))
   (progn
    (setq str10 
     (strcat                                  ; codice 10 della linea
      (rtos (car   (cdr (assoc 10 ent))) 2 6) ; estrae e formatta X
      " "
      (rtos (cadr  (cdr (assoc 10 ent))) 2 6) ; estrae e formatta Y
      " "
      (rtos (caddr (cdr (assoc 10 ent))) 2 6) ; estrae e formatta Z
     )
    )
    (setq str11 
     (strcat                                  ; codice 11 della linea
      (rtos (car   (cdr (assoc 11 ent))) 2 6) ; estrae e formatta X
      " "
      (rtos (cadr  (cdr (assoc 11 ent))) 2 6) ; estrae e formatta Y
      " "
      (rtos (caddr (cdr (assoc 11 ent))) 2 6) ; estrae e formatta Z
     )
    )
    (write-line (strcat str10 " " str11) f1)
   )
  )
  (if (= "POINT" (cdr (assoc 0 ent)))
   (progn
    (setq str10 
     (strcat                                  ; codice 10 del punto
      (rtos (car   (cdr (assoc 10 ent))) 2 6) ; estrae e formatta X
      " "
      (rtos (cadr  (cdr (assoc 10 ent))) 2 6) ; estrae e formatta Y
      " "
      (rtos (caddr (cdr (assoc 10 ent))) 2 6) ; estrae e formatta Z
     )
    )
    (write-line str10 f2)
   )
  )
  (setq k (+ k 1))
 )
 (close f1) ; chiude LINEE.TXT
 (close f2) ; chiude PUNTI.TXT
 (ripVar)   ; ripristina l'ambiente
)
;;;eof